-
Notifications
You must be signed in to change notification settings - Fork 0
/
cluster.tf
187 lines (150 loc) · 4.16 KB
/
cluster.tf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
/*
Copyright 2020 Mia srl
Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at
http://www.apache.org/licenses/LICENSE-2.0
Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
*/
resource "google_container_cluster" "master" {
provider = google-beta
project = data.google_project.prj.project_id
location = var.location
node_locations = var.zones
name = var.name
description = var.description
min_master_version = local.min_master_version
default_max_pods_per_node = 110
release_channel {
channel = "UNSPECIFIED"
}
cluster_autoscaling {
enabled = false
}
remove_default_node_pool = true
initial_node_count = 1
network = data.google_compute_subnetwork.subnetwork.network
subnetwork = data.google_compute_subnetwork.subnetwork.self_link
binary_authorization {
evaluation_mode = "DISABLED"
}
enable_intranode_visibility = false
enable_shielded_nodes = var.enable_shielded_nodes
enable_kubernetes_alpha = false
enable_legacy_abac = false
enable_tpu = false
maintenance_policy {
daily_maintenance_window {
start_time = var.maintenance_start_time
}
}
ip_allocation_policy {
cluster_secondary_range_name = var.cluster_secondary_range_name
services_secondary_range_name = var.services_secondary_range_name
}
private_cluster_config {
enable_private_nodes = true
enable_private_endpoint = var.enable_private_only_api_server
master_ipv4_cidr_block = var.master_ipv4_cidr_block
master_global_access_config {
enabled = var.master_global_access
}
}
dynamic "master_authorized_networks_config" {
for_each = local.master_authorized_networks_config
content {
dynamic "cidr_blocks" {
for_each = master_authorized_networks_config.value.cidr_blocks
content {
cidr_block = lookup(cidr_blocks.value, "cidr_block", "")
display_name = lookup(cidr_blocks.value, "display_name", "")
}
}
}
}
master_auth {
client_certificate_config {
issue_client_certificate = false
}
}
dynamic "authenticator_groups_config" {
for_each = local.authenticator_security_group
content {
security_group = authenticator_groups_config.value
}
}
network_policy {
enabled = local.gke_calico_enabled.enabled
provider = local.gke_calico_enabled.provider
}
pod_security_policy_config {
enabled = var.enable_pod_security_policies
}
workload_identity_config {
workload_pool = local.workload_identity_namespace
}
vertical_pod_autoscaling {
enabled = var.vertical_pod_autoscaling_enabled
}
logging_config {
enable_components = []
}
monitoring_config {
managed_prometheus {
enabled = false
}
}
addons_config {
http_load_balancing {
disabled = false
}
horizontal_pod_autoscaling {
disabled = false
}
network_policy_config {
disabled = local.gke_calico_enabled.enabled ? false : true
}
istio_config {
disabled = true
}
cloudrun_config {
disabled = true
}
dns_cache_config {
enabled = false
}
gce_persistent_disk_csi_driver_config {
enabled = var.csi_driver_enabled
}
kalm_config {
enabled = false
}
config_connector_config {
enabled = false
}
}
default_snat_status {
disabled = false
}
resource_labels = var.labels
timeouts {
create = "45m"
update = "45m"
delete = "45m"
}
deletion_protection = var.deletion_protection
lifecycle {
ignore_changes = [
node_pool,
initial_node_count,
min_master_version,
binary_authorization,
node_pool_auto_config,
node_pool_defaults
]
}
}